djcev.com

//==============================================================================
// trigger_void
//==============================================================================

//======================================================================
// This is necros' trigger_void from Lost Chapters pack, modified
// by dumptruck_ds, modified again by CEV
//======================================================================

//======================================================================
// constants
//======================================================================

#ifdef SSQC
//----------------------------------------------------------------------
// trigger_void spawnflags -- CEV
//----------------------------------------------------------------------
typedef enumflags
{
        SPAWNFLAG_TRIGGER_VOID_MONSTER_SAFE = 1,
        SPAWNFLAG_TRIGGER_VOID_PLAYER_SAFE = 2
        // SPAWNFLAG_NOT_ON_EASY = 256, // see base_entities.qc -- CEV
        // SPAWNFLAG_NOT_ON_NORMAL = 512,
        // SPAWNFLAG_NOT_ON_HARD_OR_NIGHTMARE = 1024,
        // SPAWNFLAG_NOT_IN_DEATHMATCH = 2048,
        // SPAWNFLAG_NOT_IN_COOP = 4096,
        // SPAWNFLAG_NOT_IN_SP = 8192,
        // SPAWNFLAG_NOT_ON_SKILL2 = 32768, // see base_entities.qc -- CEV
        // SPAWNFLAG_NOT_ON_SKILL3 = 65536, // see base_entities.qc -- CEV
        // SPAWNFLAG_CENTERPRINTALL = 131072 // see base_entities.qc -- CEV
} trigger_void_spawnflags;
#endif

//======================================================================
// forward declarations
//======================================================================

#ifdef SSQC
// trigger_void
void() trigger_void_touch;
void(entity e) trigger_void_init;
void() trigger_void;
#endif

//------------------------------------------------------------------------------

#ifdef SSQC
/*QUAKED trigger_void (.5 .5 .5) ? X X X X X X X X NOT_ON_EASY NOT_ON_NORMAL NOT_ON_HARD_OR_NIGHTMARE NOT_IN_DEATHMATCH NOT_IN_COOP NOT_IN_SINGLEPLAYER X NOT_ON_HARD_ONLY NOT_ON_NIGHTMARE_ONLY
Use this for a 'void' area.
Removes monsters, gibs, ammo, etc...  also kills player.
*/
//----------------------------------------------------------------------
// class trigger_void: base_trigger
// {
        //--------------------------------------------------------------
        void() trigger_void_touch =
        {
                if (self.estate != STATE_ACTIVE)
                        return;

                // entity has already been removed -- CEV
                if (!other)
                        return;

                // from Copper -- dumptruck_ds
                if (other.movetype == MOVETYPE_NOCLIP)
                        return FALSE;

                if (self.spawnflags & SPAWNFLAG_TRIGGER_VOID_MONSTER_SAFE &&
                        other.flags & FL_MONSTER)
                {
                        // ignore monsters
                        return;
                }

                if (self.spawnflags & SPAWNFLAG_TRIGGER_VOID_PLAYER_SAFE &&
                        other.flags & FL_CLIENT)
                {
                        // ignore players
                        return;
                }

                // ignore player heads -- CEV
                if (other.classtype == CT_ITEM_HEAD_PLAYER)
                        return;

                if (other.takedamage)
                {
                        // kills even with Pentagram, this took forever to
                        // figure out!! -- dumptruck_ds
                        other.invincible_finished = 0;
                        t_damage2 (other, self, self, other.health + 1000);

                        if (other.flags & FL_MONSTER)
                                base_entity_remove (other);
                }
                else if (other.classtype != CT_PLAYER)
                {
                        // remove projectiles -- CEV
                        if (other.classgroup & CG_PROJECTILE)
                                base_entity_remove (other);

                        // remove corpses - gibs, heads, bodies -- CEV
                        if (other.classgroup & CG_CORPSE)
                                base_entity_remove (other);

                        // remove all items -- CEV
                        if (other.classgroup & CG_ITEM)
                                base_entity_remove (other);
                }

                force_retouch = 2;
        };

        //--------------------------------------------------------------
        void(entity e) trigger_void_init =
        {
                e.classname = "trigger_void";
                e.classtype = CT_TRIGGER_VOID;
                e.touch = trigger_void_touch;
                base_trigger_init (e);
                sub_checkwaiting (e);
        };

        //--------------------------------------------------------------
        void() trigger_void =
        {
                // new spawnflags for all entities -- iw
                if (SUB_Inhibit())
                        return;

                trigger_void_init (self);
        };
// };
#endif