djcev.com

//==============================================================================
// trigger_secret
//==============================================================================

//======================================================================
// forward declarations
//======================================================================

#ifdef SSQC
// trigger_secret
void(entity e) trigger_secret_init;
void() trigger_secret;
#endif

//------------------------------------------------------------------------------

#ifdef SSQC
/*QUAKED trigger_secret (.5 .5 .5) ? X X X X X X X X NOT_ON_EASY NOT_ON_NORMAL NOT_ON_HARD_OR_NIGHTMARE NOT_IN_DEATHMATCH NOT_IN_COOP NOT_IN_SINGLEPLAYER X NOT_ON_HARD_ONLY NOT_ON_NIGHTMARE_ONLY
secret counter trigger
sounds
1) secret
2) beep beep
set "message" to text string
*/
//----------------------------------------------------------------------
// class trigger_secret: base_multiple
// {
        //--------------------------------------------------------------
        void(entity e) trigger_secret_init =
        {
                e.classname = "trigger_secret";
                e.classtype = CT_TRIGGER_SECRET;

                total_secrets = total_secrets + 1;
                e.wait = -1;

                if (!e.message)
                        e.message = "You found a secret area!";

                if (!e.sounds)
                        e.sounds = 1;

                if (e.sounds == 1)
                {
                        precache_sound ("misc/secret.wav");
                        e.noise = "misc/secret.wav";
                }
                else if (e.sounds == 2)
                {
                        precache_sound ("misc/talk.wav");
                        e.noise = "misc/talk.wav";
                }

                base_multiple_init (e);
        };

        //--------------------------------------------------------------
        void() trigger_secret =
        {
                // new spawnflags for all entities -- iw
                if (SUB_Inhibit())
                        return;

                trigger_secret_init (self);
        };
// };
#endif