djcev.com

//==============================================================================
// misc_rune_indicator -- MG1 rune indicators from items_runes.qc -- CEV
//==============================================================================

//======================================================================
// constants
//======================================================================

#ifdef SSQC
//----------------------------------------------------------------------
// rune indicator spawnflags -- CEV
//----------------------------------------------------------------------
typedef enumflags
{
        // SPAWNFLAG_ITEM_SIGIL_RUNE1 = 1, // see items/runes.qc -- CEV
        // SPAWNFLAG_ITEM_SIGIL_RUNE2 = 2, // rune 2
        // SPAWNFLAG_ITEM_SIGIL_RUNE3 = 4, // rune 3
        // SPAWNFLAG_ITEM_SIGIL_RUNE4 = 8, // rune 4
        // SPAWNFLAG_ITEM_SIGIL_RUNE5 = 16,// rune 5
        // SPAWNFLAG_ITEM_SIGIL_RUNE6 = 32,// rune 6
        SPAWNFLAG_RUNE_INDICATOR_ACTIVE = 64 // MG1 active rune indicator -- CEV
        // SPAWNFLAG_NOT_ON_EASY = 256, // see base_entities.qc -- CEV
        // SPAWNFLAG_NOT_ON_NORMAL = 512,
        // SPAWNFLAG_NOT_ON_HARD_OR_NIGHTMARE = 1024,
        // SPAWNFLAG_NOT_IN_DEATHMATCH = 2048,
        // SPAWNFLAG_NOT_IN_COOP = 4096,
        // SPAWNFLAG_NOT_IN_SP = 8192,
        // SPAWNFLAG_NOT_ON_SKILL2 = 32768, // see base_entities.qc -- CEV
        // SPAWNFLAG_NOT_ON_SKILL3 = 65536 // see base_entities.qc -- CEV
        // SPAWNFLAG_CENTERPRINTALL = 131072 // see base_entities.qc -- CEV
} misc_rune_indicator_spawnflags;
#endif

#ifdef SSQC
const float SIGIL_AL = SPAWNFLAG_ITEM_SIGIL_RUNE1 | SPAWNFLAG_ITEM_SIGIL_RUNE2 |
        SPAWNFLAG_ITEM_SIGIL_RUNE3 | SPAWNFLAG_ITEM_SIGIL_RUNE4;
const float SIGIL_ALL = SPAWNFLAG_ITEM_SIGIL_RUNE1 |
        SPAWNFLAG_ITEM_SIGIL_RUNE2 | SPAWNFLAG_ITEM_SIGIL_RUNE3 |
        SPAWNFLAG_ITEM_SIGIL_RUNE4 | SPAWNFLAG_ITEM_SIGIL_RUNE5;
const float SIGIL_ALL_ALL_ALLLL = SPAWNFLAG_ITEM_SIGIL_RUNE1 |
        SPAWNFLAG_ITEM_SIGIL_RUNE2 | SPAWNFLAG_ITEM_SIGIL_RUNE3 |
        SPAWNFLAG_ITEM_SIGIL_RUNE4 | SPAWNFLAG_ITEM_SIGIL_RUNE5 |
        SPAWNFLAG_ITEM_SIGIL_RUNE6;
#endif

//======================================================================
// forward declarations
//======================================================================

#ifdef SSQC
// misc_rune_indicator
void() misc_rune_indicator_use;
void(entity e) misc_rune_indicator_init;
void() misc_rune_indicator;
#endif

//------------------------------------------------------------------------------

#ifdef SSQC
//----------------------------------------------------------------------
// class misc_rune_indicator: base_mapentity
// {
        //--------------------------------------------------------------
        void() misc_rune_indicator_use =
        {
                self.alpha = 1.0;
                sub_usetargets ();
        };

        //--------------------------------------------------------------
        void(entity e) misc_rune_indicator_init =
        {
                e.classname = "misc_rune_indicator";
                e.classtype = CT_MISC_RUNE_INDICATOR;
                base_mapentity_init (e);

                local float active = e.spawnflags &
                        SPAWNFLAG_RUNE_INDICATOR_ACTIVE ? TRUE : FALSE;
                e.spawnflags &= ~SPAWNFLAG_RUNE_INDICATOR_ACTIVE;

                if (!e.spawnflags)
                        e.spawnflags |= SPAWNFLAG_ITEM_SIGIL_RUNE1;

                e.spawnflags &= SIGIL_ALL_ALL_ALLLL;

                e.mdl = "";

                if (e.spawnflags & SPAWNFLAG_ITEM_SIGIL_RUNE1)
                {
                        e.spawnflags = SPAWNFLAG_ITEM_SIGIL_RUNE1;
                        if (known_release == KNOWN_RELEASE_MG1)
                                e.mdl = "progs/mg1_rune1.mdl";
                        else
                                e.mdl = "progs/end1.mdl";
                }
                else if (e.spawnflags & SPAWNFLAG_ITEM_SIGIL_RUNE2)
                {
                        e.spawnflags = SPAWNFLAG_ITEM_SIGIL_RUNE2;
                        if (known_release == KNOWN_RELEASE_MG1)
                                e.mdl = "progs/mg1_rune2.mdl";
                        else
                                e.mdl = "progs/end2.mdl";
                }
                else if (e.spawnflags & SPAWNFLAG_ITEM_SIGIL_RUNE3)
                {
                        e.spawnflags = SPAWNFLAG_ITEM_SIGIL_RUNE3;
                        if (known_release == KNOWN_RELEASE_MG1)
                                e.mdl = "progs/mg1_rune3.mdl";
                        else
                                e.mdl = "progs/end3.mdl";
                }
                else if (e.spawnflags & SPAWNFLAG_ITEM_SIGIL_RUNE4)
                {
                        e.spawnflags = SPAWNFLAG_ITEM_SIGIL_RUNE4;
                        if (known_release == KNOWN_RELEASE_MG1)
                                e.mdl = "progs/mg1_rune4.mdl";
                        else
                                e.mdl = "progs/end4.mdl";
                }
                else if (known_release == KNOWN_RELEASE_MG1)
                {
                        if (e.spawnflags & SPAWNFLAG_ITEM_SIGIL_RUNE5)
                        {
                                e.spawnflags = SPAWNFLAG_ITEM_SIGIL_RUNE5;
                                e.mdl = "progs/mg1_rune5.mdl";
                        }
                        else if (e.spawnflags & SPAWNFLAG_ITEM_SIGIL_RUNE6)
                        {
                                e.spawnflags = SPAWNFLAG_ITEM_SIGIL_RUNE6;
                                e.mdl = "progs/mg1_rune6.mdl";
                        }
                }
    
                precache_model (e.mdl);
                setmodel (e, e.mdl);

                e.use = misc_rune_indicator_use;

                if(((e.spawnflags & serverflags) == e.spawnflags) || active)
                {
                        e.think = sub_usetargets;
                        e.nextthink = time + 0.2;
                }
                else
                {
                        // Show a ghost of the rune before you collect it.
                        e.alpha = 0.2;
                }
        };

        //--------------------------------------------------------------
        void() misc_rune_indicator =
        {
                // new spawnflags for all entities -- iw
                if (SUB_Inhibit())
                        return;

                misc_rune_indicator_init (self);
        };
// };
#endif