djcev.com

//==============================================================================
// particle_tele -- selections from MachineGames misc_fx.qc -- CEV
//==============================================================================

//======================================================================
// constants
//======================================================================

#ifdef SSQC
//----------------------------------------------------------------------
// misc_particle_tele spawnflags -- CEV
//----------------------------------------------------------------------
typedef enumflags
{
        SPAWNFLAG_MISC_PARTICLE_TELE_START_OFF = 1
        // SPAWNFLAG_NOT_ON_EASY = 256, // see base_entities.qc -- CEV
        // SPAWNFLAG_NOT_ON_NORMAL = 512,
        // SPAWNFLAG_NOT_ON_HARD_OR_NIGHTMARE = 1024,
        // SPAWNFLAG_NOT_IN_DEATHMATCH = 2048,
        // SPAWNFLAG_NOT_IN_COOP = 4096,
        // SPAWNFLAG_NOT_IN_SP = 8192,
        // SPAWNFLAG_NOT_ON_SKILL2 = 32768, // see base_entities.qc -- CEV
        // SPAWNFLAG_NOT_ON_SKILL3 = 65536, // see base_entities.qc -- CEV
        // SPAWNFLAG_CENTERPRINTALL = 131072 // see base_entities.qc -- CEV
} misc_particle_tele_spawnflags;
#endif

//======================================================================
// forward declarations
//======================================================================

#ifdef SSQC
// particle_tele
void() particle_tele_think;
void(entity e) particle_tele_init;
void() particle_tele;
#endif

#ifdef SSQC
// particle_tele_fountain
void() particle_tele_fountain_think;
void() particle_tele_fountain_use;
void(entity e) particle_tele_fountain_init;
void() particle_tele_fountain;
#endif

//------------------------------------------------------------------------------

#ifdef SSQC
//----------------------------------------------------------------------
// class particle_tele: base_mapentity
// {
        //--------------------------------------------------------------
        void() particle_tele_think =
        {
                // where to spawn
                local vector pos;
                // scalar from org, used for speed too
                local float dist = 64;
                local vector rando;
        
                rando_x = crandom() * 10;
                rando_y = crandom() * 10;
                rando_z = crandom() * 5;
                rando = normalize(rando);
        
                pos = self.origin + (rando * dist);
        
                // spawn particle
                particle (pos, rando * dist * -.125, 3, 3);
                self.nextthink = time + self.wait + self.delay * random();
        };

        //--------------------------------------------------------------
        void(entity e) particle_tele_init =
        {
                e.classname = "particle_tele";
                e.classtype = CT_MISC_PARTICLE_TELE;
                base_mapentity_init (e);

                /*
                1. get origin
                2. get a random vector, then normalize it. Save it for later
                3. scale a copy of the vector by distance
                4. spawn the particle at vector + origin
                5. set the particle's vel to the old normalized vector * -scalar
                */

                // size determines the box the particles can spawn within
                if (!e.size)
                        e.size = '128 128 0';
                // delay is random time added per loop
                if (!e.delay)
                        e.delay = 0.1;
        
                // wait is time always added per loop
                if (!e.wait)
                        e.wait = 0;
        
                e.think = particle_tele_think;
                e.nextthink = time + e.wait + e.delay * random();
        };

        //--------------------------------------------------------------
        void() particle_tele =
        {
                // new spawnflags for all entities -- iw
                if (SUB_Inhibit())
                        return;

                particle_tele_init (self);
        };
// };
#endif

#ifdef SSQC
//----------------------------------------------------------------------
// class particle_tele_fountain: base_mapentity
// {
        //--------------------------------------------------------------
        void() particle_tele_fountain_think =
        {
                local vector dir;
                dir_x = crandom() * self.velocity_x;
                dir_y = crandom() * self.velocity_y;
                dir_z = self.velocity_z;
                particle (self.origin, dir, 13, 2);
                self.nextthink = time + self.wait + self.delay * random();
        };

        //--------------------------------------------------------------
        void() particle_tele_fountain_use =
        {
                self.think = particle_tele_fountain_think;
                self.nextthink = time + 0.1;
        };

        //--------------------------------------------------------------
        void(entity e) particle_tele_fountain_init =
        {
                e.classname = "particle_tele_fountain";
                e.classtype = CT_MISC_PARTICLE_TELE_FOUNTAIN;
                base_mapentity_init (e);

                if (!e.delay)
                        e.delay = 0.1;
        
                if (!e.wait)
                        e.wait = 0.05;
        
                if (!e.velocity)
                        e.velocity = '1 1 6';
        
                if (e.spawnflags & SPAWNFLAG_MISC_PARTICLE_TELE_START_OFF)
                {
                        e.use = particle_tele_fountain_use;
                }
                else
                {
                        e.think = particle_tele_fountain_think;
                        e.nextthink = time + e.wait + e.delay * random();
                }
        };

        //--------------------------------------------------------------
        void() particle_tele_fountain =
        {
                // new spawnflags for all entities -- iw
                if (SUB_Inhibit())
                        return;

                particle_tele_fountain_init (self);
        };
// };
#endif