djcev.com

//==============================================================================
// info_intermission
//==============================================================================

//======================================================================
// forward declarations
//======================================================================

// info_intermission
entity(entity src, vector org) spawn_info_intermission;
void(entity e) info_intermission_init;
void() info_intermission;

// info_intermissiontext
entity(entity src, vector org, string smsg, float fcnt)
        spawn_info_intermissiontext;
void(entity e) info_intermissiontext_init;
void() info_intermissiontext;

//------------------------------------------------------------------------------

/*QUAKED info_intermission (1 0.5 0.5) (-16 -16 -16) (16 16 16) X X X X X X X X NOT_ON_EASY NOT_ON_NORMAL NOT_ON_HARD_OR_NIGHTMARE NOT_IN_DEATHMATCH NOT_IN_COOP NOT_IN_SINGLEPLAYER X NOT_ON_HARD_ONLY NOT_ON_NIGHTMARE_ONLY

This is the camera point for the intermission.
Use mangle instead of angle, so you can set pitch or roll as well as yaw.  'pitch roll yaw'
*/

//----------------------------------------------------------------------
// class info_intermission: base_mapentity
// {
        //--------------------------------------------------------------
        entity(entity src, vector org) spawn_info_intermission =
        {
                local entity e = spawn ();
                e.owner = src;
                e.origin = org;
                info_intermission_init (e);
                return e;
        };

        //--------------------------------------------------------------
        void(entity e) info_intermission_init =
        {
                base_mapentity_init (e);
                e.classname = "info_intermission";
                e.classtype = CT_INFO_INTERMISSION;
        };

        //--------------------------------------------------------------
        void() info_intermission =
        {
                // new spawnflags for all entities -- iw
                if (SUB_Inhibit())
                        return;

                info_intermission_init (self);
        };
// };

//----------------------------------------------------------------------
// class info_intermissiontext: base_mapentity
// {
        //--------------------------------------------------------------
        entity(entity src, vector org, string smsg, float fcnt)
                spawn_info_intermissiontext =
        {
                local entity e = spawn ();
                e.origin = org;
                e.message = smsg;
                e.cnt = fcnt;
                info_intermissiontext_init (e);
                return e;
        };

        //--------------------------------------------------------------
        void(entity e) info_intermissiontext_init =
        {
                base_mapentity_init (e);
                e.classname = "info_intermissiontext";
                e.classtype = CT_INFO_INTERMISSIONTEXT;

                if (e.message == "" || e.cnt == 0)
                {
                        objerror (sprintf("info_intermissiontext_init: "
                                "endscreen lacks required fields: message %s"
                                ", cnt %g\n", e.message, e.cnt));
                }
        };

        //--------------------------------------------------------------
        void() info_intermissiontext =
        {
                // new spawnflags for all entities -- iw
                if (SUB_Inhibit())
                        return;

                info_intermissiontext_init (self);
        };
// };