djcev.com

//==============================================================================
// func_episodegate
//==============================================================================

//======================================================================
// constants
//======================================================================

// For func_episodegate and func_bossgate appear when player has all runes
const float EPISODEGATE_REVERSE = 16;

//======================================================================
// forward declarations
//======================================================================

// func_episodegate
void(entity e) func_episodegate_init;
void() func_episodegate;

//------------------------------------------------------------------------------

/*QUAKED func_episodegate (0 .5 .8) ? E1 E2 E3 E4 REVERSE_FUNCTIONALITY
This bmodel will appear if the episode has allready been completed, so players can't reenter it.
*/
//----------------------------------------------------------------------
// class func_episodegate: base_func_wall
// {
        //--------------------------------------------------------------
        void(entity e) func_episodegate_init =
        {
                e.classname = "func_episodegate";
                e.classtype = CT_FUNC_EPISODEGATE;
                base_func_wall_init (e);

                if (e.spawnflags & EPISODEGATE_REVERSE)
                {
                        // this is to avoid a possible issue with sigil_touch2
                        e.spawnflags = e.spawnflags - EPISODEGATE_REVERSE;
                        if (serverflags & e.spawnflags)
                                // Haven't gotten rune yet
                                return;
                }
                else
                {
                        if (!(serverflags & e.spawnflags))
                                // can still enter episode
                                return;
                }

                e.angles = '0 0 0';
                // so it doesn't get pushed by anything
                e.movetype = MOVETYPE_PUSH;
                e.solid = SOLID_BSP;
                setmodel (e, e.model);
        };

        //--------------------------------------------------------------
        void() func_episodegate =
        {
                // new spawnflags for all entities -- iw
                if (SUB_Inhibit())
                        return;

                func_episodegate_init (self);
        };
// };