djcev.com

//==============================================================================
// func_button -- button and multiple button
//==============================================================================

//======================================================================
// constants
//======================================================================

#ifdef SSQC
//----------------------------------------------------------------------
// func_button spawnflags -- CEV
//----------------------------------------------------------------------
typedef enumflags
{
        SPAWNFLAG_FUNC_BUTTON_KEY_ALWAYS_REQUIRED = 32 // MG1 compat -- CEV
        // SPAWNFLAG_NOT_ON_EASY = 256, // see base_entities.qc -- CEV
        // SPAWNFLAG_NOT_ON_NORMAL = 512,
        // SPAWNFLAG_NOT_ON_HARD_OR_NIGHTMARE = 1024,
        // SPAWNFLAG_NOT_IN_DEATHMATCH = 2048,
        // SPAWNFLAG_NOT_IN_COOP = 4096,
        // SPAWNFLAG_NOT_IN_SP = 8192,
        // SPAWNFLAG_NOT_ON_SKILL2 = 32768, // see base_entities.qc -- CEV
        // SPAWNFLAG_NOT_ON_SKILL3 = 65536, // see base_entities.qc -- CEV
        // SPAWNFLAG_CENTERPRINTALL = 131072 // see base_entities.qc -- CEV
} func_button_spawnflags;
#endif

//======================================================================
// forward declarations
//======================================================================

// func_button
#ifdef CSQC
void(float isnew) func_button_netreceive;
#endif
#ifdef SSQC
void() func_button_think_wait;
void() func_button_think_done;
void() func_button_think_return;
void() func_button_blocked;
void() func_button_fire;
void(vector dir) func_button_destroy;
void() func_button_use;
void() func_button_touch;
void(entity b) func_button_lock;
void(entity b, float dontresetstate) func_button_unlock;
#endif
#if defined(CSQC) || defined(SSQC)
void(entity e) func_button_init;
#endif
#ifdef SSQC
void() func_button;
#endif

//------------------------------------------------------------------------------

/*QUAKED func_button (0 .5 .8) ? X X X X X X X X NOT_ON_EASY NOT_ON_NORMAL NOT_ON_HARD_OR_NIGHTMARE NOT_IN_DEATHMATCH NOT_IN_COOP NOT_IN_SINGLEPLAYER X NOT_ON_HARD_ONLY NOT_ON_NIGHTMARE_ONLY
When a button is touched, it moves some distance in the direction of it's angle, triggers all of it's targets, waits some time, then returns to it's original position where it can be triggered again.

"angle" determines the opening direction
"target"        all entities with a matching targetname will be used
"speed" override the default 40 speed
"wait"  override the default 1 second wait (-1 = never return)
"lip"   override the default 4 pixel lip remaining at end of move
"health"        if set, the button must be killed instead of touched
"sounds"
0) steam metal
1) wooden clunk
2) metallic click
3) in-out
*/
//----------------------------------------------------------------------
// class func_button: base_func
// {
#ifdef CSQC
        //--------------------------------------------------------------
        void(float isnew) func_button_netreceive =
        {
                // creates the netflag variable -- CEV
                BASE_FUNC_NETRECEIVE (func_button_init)

                if (isnew)
                        base_entity_que_add (self, QUE_TYPE_ACTOR);
        };
#endif

#ifdef SSQC
        //--------------------------------------------------------------
        void() func_button_think_wait =
        {
                self.state = FUNC_STATE_TOP;

                self.think = func_button_think_return;
                self.nextthink = self.ltime + self.wait;
                activator = self.enemy;

                // use alternate textures
                self.frame = 1;
                self.SendFlags |= NETFLAG_BASE_ENTITY_FRAME |
                        NETFLAG_BASE_ENTITY_ORIGIN;

                if (self.estate != STATE_ACTIVE)
                        return;

                sub_usetargets ();
        };

        //--------------------------------------------------------------
        void() func_button_think_done =
        {
                self.SendFlags |= NETFLAG_BASE_ENTITY_ORIGIN;
                self.state = FUNC_STATE_BOTTOM;
        };

        //--------------------------------------------------------------
        void() func_button_think_return =
        {
                if (self.estate != STATE_ACTIVE)
                        return;

                self.state = FUNC_STATE_DOWN;
                base_func_calcmove (self, self.pos1, self.speed,
                        func_button_think_done);

                // use normal textures
                self.frame = 0;
                self.SendFlags |= NETFLAG_BASE_ENTITY_FRAME;

                if (self.health)
                        // can be shot again
                        self.takedamage = DAMAGE_YES;
        };

        //--------------------------------------------------------------
        void() func_button_blocked =
        {
                // do nothing, just don't come all the way back out
        };

        //--------------------------------------------------------------
        void() func_button_fire =
        {
                if (self.estate != STATE_ACTIVE)
                        return;

                if (self.state == FUNC_STATE_UP || self.state == FUNC_STATE_TOP)
                        return;

                // MG1 compat -- CEV
                if (known_release == KNOWN_RELEASE_MG1) {
                if (self.items)
                {
                        sound (self, CHAN_ITEM, self.noise4, 1, ATTN_NORM);
                        if (!(self.spawnflags &
                                SPAWNFLAG_FUNC_BUTTON_KEY_ALWAYS_REQUIRED))
                        {
                                self.items = 0;
                        }
                } }

                sound (self, CHAN_VOICE, self.noise, VOL_MID, ATTN_NORM);

                self.state = FUNC_STATE_UP;
                base_func_calcmove (self, self.pos2, self.speed,
                        func_button_think_wait);
        };

        //--------------------------------------------------------------
        void(vector dir) func_button_destroy =
        {
                if (self.estate != STATE_ACTIVE)
                        return;

                self.enemy = damage_attacker;
                self.health = self.max_health;
                // wil be reset upon return
                self.takedamage = DAMAGE_NO;

                func_button_fire ();
        };

        //--------------------------------------------------------------
        void() func_button_use =
        {
                self.enemy = activator;
                func_button_fire ();
        };

        //--------------------------------------------------------------
        void() func_button_touch =
        {
                if (self.health)
                        return;

                if (other.classtype != CT_PLAYER)
                        return;

                self.enemy = other;
                func_button_fire ();
        };

        //--------------------------------------------------------------
        // adapted from Copper, thanks Lunaran -- modified again by CEV
        //--------------------------------------------------------------
        void(entity b) func_button_lock =
        {
                if (b.estate == STATE_INACTIVE)
                        return;

                if (b.state == FUNC_STATE_UP || b.state == FUNC_STATE_TOP)
                        b.prevstate = FUNC_STATE_TOP;
                else
                        b.prevstate = FUNC_STATE_BOTTOM;

                if (b.max_health)
                        b.takedamage = DAMAGE_NO;

                b.state = FUNC_STATE_UP;
                base_func_calcmove (b, b.pos2, b.speed, func_button_think_wait);
                b.estate = STATE_INACTIVE;
        };

        //--------------------------------------------------------------
        void(entity b, float dontresetstate) func_button_unlock =
        {
                if (b.estate == STATE_ACTIVE)
                        return;

                if (!dontresetstate || b.wait != -1 ||
                        b.prevstate == FUNC_STATE_BOTTOM)
                {
                        if (b.max_health)
                        {
                                b.takedamage = DAMAGE_YES;
                                b.health = b.max_health;
                        }

                        // use normal textures
                        b.frame = 0;
                        b.state = FUNC_STATE_DOWN;
                        base_func_calcmove (b, b.pos1, b.speed,
                                func_button_think_done);
                }

                b.estate = STATE_ACTIVE;
        };
#endif

#if defined(CSQC) || defined(SSQC)
        //--------------------------------------------------------------
        void(entity e) func_button_init =
        {
                e.classname = "func_button";
                e.classtype = CT_FUNC_BUTTON;

                base_func_init (e);

                #ifdef CSQC
                setmodelindex (e, e.modelindex);
                setsize (e, e.mins, e.maxs);
                setorigin (e, e.origin);
                e.drawmask = DRAWMASK_NORMAL;
                e.predraw = base_func_predraw;
                #endif

                #ifdef SSQC
                if (e.sounds == 0)
                {
                        precache_sound ("buttons/airbut1.wav");
                        e.noise = "buttons/airbut1.wav";
                }

                if (e.sounds == 1)
                {
                        precache_sound ("buttons/switch21.wav");
                        e.noise = "buttons/switch21.wav";
                }

                if (e.sounds == 2)
                {
                        precache_sound ("buttons/switch02.wav");
                        e.noise = "buttons/switch02.wav";
                }

                if (e.sounds == 3)
                {
                        precache_sound ("buttons/switch04.wav");
                        e.noise = "buttons/switch04.wav";
                }

                e.movetype = MOVETYPE_PUSH;
                e.solid = SOLID_BSP;
                e.blocked = func_button_blocked;
                e.use = func_button_use;
                setmodel (e, e.model);

                if (e.health)
                {
                        e.max_health = e.health;
                        e.takedamage = DAMAGE_YES;
                        e.destroy = func_button_destroy;
                }
                else
                {
                        e.touch = func_button_touch;
                }

                if (!e.speed)
                        e.speed = 40;
                if (!e.wait)
                        e.wait = 1;
                if (!e.lip)
                        e.lip = 4;

                e.state = FUNC_STATE_BOTTOM;

                // MG1 compat -- CEV
                if (e.movedir)
                {
                        e.pos1 = e.origin;
                        e.pos2 = e.pos1 + e.movedir;
                        e.angles = '0 0 0';
                }
                else
                {
                        sub_setmovedir (e);
                        e.pos1 = e.origin;
                        e.pos2 = e.pos1 + e.movedir *
                                (fabs(e.movedir * e.size) - e.lip);
                }

                // network to CSQC -- CEV
                e.tick = base_func_neteval;
                e.SendEntity = base_entity_netsend;
                e.SendFlags = NETFLAG_BASE_ENTITY_FULLSEND;
                #endif
        };
#endif

#ifdef SSQC
        //--------------------------------------------------------------
        void() func_button =
        {
                // new spawnflags for all entities -- iw
                if (SUB_Inhibit())
                        return;

                func_button_init (self);
        };
#endif
// };