djcev.com

//==============================================================================
// func_bossgate
//==============================================================================

//======================================================================
// Constants
//======================================================================

#ifdef SSQC
// For func_episodegate and func_bossgate appear when player has all runes
const float BOSSGATE_REVERSE = 16;
#endif

//======================================================================
// forward declarations
//======================================================================

// func_bossgate
#ifdef SSQC
void(entity e) func_bossgate_init;
void() func_bossgate;
#endif

//------------------------------------------------------------------------------

/*QUAKED func_bossgate (0 .5 .8) ? X X X X REVERSE_FUNCTIONALITY
This bmodel appears unless players have all of the episode sigils.
*/
//----------------------------------------------------------------------
// class func_bossgate: base_func_wall
// {
#ifdef SSQC
        //--------------------------------------------------------------
        void(entity e) func_bossgate_init =
        {
                e.classname = "func_bossgate";
                e.classtype = CT_FUNC_BOSSGATE;

                // will set use -- CEV
                base_func_wall_init (e);

                if (e.spawnflags & BOSSGATE_REVERSE)
                {
                        if (!((serverflags & 15) == 15))
                        {
                                // not all complete
                                return;
                        }
                }
                else
                {
                        if ((serverflags & 15) == 15)
                                // all episodes completed
                                return;
                }

                e.angles = '0 0 0';
                // so it doesn't get pushed by anything
                e.movetype = MOVETYPE_PUSH;
                e.solid = SOLID_BSP;
                setmodel (e, e.model);
        };

        //--------------------------------------------------------------
        void() func_bossgate =
        {
                // new spawnflags for all entities -- iw
                if (SUB_Inhibit())
                        return;

                func_bossgate_init (self);
        };
#endif
// };