djcev.com

//==============================================================================
// cshift.qc
//==============================================================================

//======================================================================
// fields
//======================================================================

.entity csf_controller;                 // cshift controller
.vector csf_color;
.float csf_density;
.float fade_amt;

//======================================================================
// forward declarations
//======================================================================

inline void(entity client, float density, vector color) csf_save;
inline void(entity client) csf_apply;
void(entity client, float density, vector color) csf_set;
void() csf_controller_think;
void(entity client) csf_controller_start;
void(entity client, float density, vector color, float spd) csf_fade;

//------------------------------------------------------------------------------

//----------------------------------------------------------------------
inline void(entity client, float density, vector color) csf_save =
{
        client.csf_color = color;
        client.csf_density = density;
};

//----------------------------------------------------------------------
inline void(entity client) csf_apply =
{
        stuffcmd (client, "\nv_cshift ");
        stuffcmd (client, ftos(client.csf_color_x));
        stuffcmd (client, " ");
        stuffcmd (client, ftos(client.csf_color_y));
        stuffcmd (client, " ");
        stuffcmd (client, ftos(client.csf_color_z));
        stuffcmd (client, " ");
        stuffcmd (client, ftos(client.csf_density));
        stuffcmd (client, "\n");
};

//----------------------------------------------------------------------
void(entity client, float density, vector color) csf_set =
{
        csf_save (client, density, color);
        csf_apply (client);
};

//----------------------------------------------------------------------
void() csf_controller_think =
{
        entity e = self.owner;

        if (self.pain_finished > time && e.csf_density != self.csf_density)
        {
                local float density, fraction;
                local vector color;

                // wat
                fraction = 1 - (self.pain_finished - time) / self.speed;

                density = lerp_hermite (e.csf_density, self.csf_density,
                        fraction);
                color = lerp_vector_hermite (e.csf_color, self.csf_color,
                        fraction);

                csf_set (e, density, color);

                self.nextthink = time + 0.04;
        }
        else
        {
                csf_set (e, self.csf_density, self.csf_color);
        }
};

//----------------------------------------------------------------------
void(entity client) csf_controller_start =
{
        if (client.csf_controller.classname == "csfcontroller" &&
                client.csf_controller.owner == client)
        {
                return;
        }

        entity e = spawn ();
        client.csf_controller = e;
        e.owner = client;
        e.classname = "csfcontroller";
        e.think = csf_controller_think;
};

//----------------------------------------------------------------------
void(entity client, float density, vector color, float spd) csf_fade =
{
        csf_controller_start (client);

        entity ct = client.csf_controller;

        ct.speed = spd;
        ct.pain_finished = time + spd;
        ct.csf_color = color;
        ct.csf_density = density;
        ct.nextthink = time + 0.04;
};